A quick INNO setup runtime installer

Read this (http://www.jrsoftware.org/ishowto.phtml?a=vb) page on the INNO website first!

After playing a while with INNO setup and reading all the posts on the forum I decided to write down the setup file list I use when creating a runtime installer only.
I decided to create a single runtime installer because it includes all the controls I most of the time use in the program I distribute.
Advantage, only 1 setup (installer) to maintain.

We need to include the basic VB6 runtime files and the other controls we want to use.
Don't use the files from your own system directory! But use the original files from the Microsoft website.

Download the original VBRUN60sp5.exe (http://download.microsoft.com/download/vb60pro/Redist/sp5/WIN98Me/EN-US/vbrun60sp5.exe) from the MS website.
Create a directory c:\vbfiles
Extract the files, don't double click VBRUN60sp5.exe, but run it from the commandline: vbrun60sp5.exe /c /t:c:\vbfiles


A quick summary of the files needed when using the INNO setup plus how it will look in the INNO installer file (*.iss)

[Setup]
AppName=VB Runtimes
AppVerName=VB Runtimes 1.0
AppPublisher=YourCompany Name
AppPublisherURL=http://www.yoursite.com
AppSupportURL=http://www.yoursite.com
AppUpdatesURL=http://www.yoursite.com
AdminPrivilegesRequired=1
; CreateAppDir=no -> To create a runtime installer only!
CreateAppDir=no
; uncomment the following line if you want your installation to run on NT 3.51 too.
; MinVersion=4,3.51

[Files]
; begin VB system files
Source: "c:\vbfiles\stdole2.tlb"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regtypelib
Source: "c:\vbfiles\msvbvm60.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\vbfiles\oleaut32.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\vbfiles\olepro32.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\vbfiles\asycfilt.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile
Source: "c:\vbfiles\comcat.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
; end VB system files
;
; Specific control you included in your project(s)
; always use the following parameters for an OCX:
; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
;
Source: "C:\WINNT\system32\COMDLG32.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "C:\WINNT\system32\riched32.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile
Source: "C:\WINNT\system32\RICHTX32.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "C:\WINNT\system32\MSCOMCTL.OCX"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
;
; Some external controls I use all of the time
;
Source: "C:\WINNT\system32\VSPRINT7.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "C:\WINNT\system32\vsPDF.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: "C:\WINNT\system32\Vsflex7L.ocx"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
;
; a normal DLL for data compression, which I use a lot
;
Source: "C:\WINNT\system32\zlib.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: sharedfile

Some info when distributing MDAC, DCOM9x too:

; -------------------------------------------------------------------------------------------------------------------------------
;
; Author: Michael Reitz
; eMail: alpha@assimilate.de
;
; This InnoSetup script shows how to install the Visual Basic Runtime files, DCOM and MDAC.
; You should go to the following webpages for dowloading the files and getting the most current information about the components:
; VB Runtime files: How-To Article on http://www.jrsoftware.org/ishowto.phtml?a=vb and http://msdn.microsoft.com/vstudio/
; DCOM: http://www.microsoft.com/com/dcom/dcom95/dcom1_3.asp and http://www.microsoft.com/com/dcom/dcom98/dcom1_3.asp
; MDAC: http://www.microsoft.com/data/
; Recommended release versions (March 2001):
; - Visual Basic 5.0 Sp3
; - Visual Basic 6.0 Sp5
; - DCOM 1.3
; - MDAC 2.5 Sp1 (contains ADO 2.5, Microsoft Jet 4.0, OLE DB Providers for SQL-Server 7.0 / MSDE 1.0 and SQL-Server 6.5)
; -> MDAC 2.5 is the version that comes with Windows 2000 SP1
; -> MDAC 2.0 and above require DCOM on Windows 95 machines for installing successfully
; -> There are some issues with existing Microsoft ODBC Driver for Access, version 3.51
; - MDAC 2.6 (contains ADO 2.6, OLE DB Provider for SQL-Server 2000)
; -> MDAC 2.6 has some issues with SQL 7.0 or SQL 6.5 Clustered Servers
; -> MDAC 2.6 doesn't contain Microsoft Jet drivers
;
; -------------------------------------------------------------------------------------------------------------------------------

; This script was first created by ISTool
; http://www.lerstad.com/istool/

[Setup]
OutputDir=.
OutputBaseFilename=VB_DCOM_MDAC_Setup
AppName=VB - DCOM - MDAC
AppVerName=VB - DCOM - MDAC
MinVersion=4.0,4.0
AdminPrivilegesRequired=true
CreateAppDir=false
DisableProgramGroupPage=true
DisableStartupPrompt=true
ShowComponentSizes=false
Uninstallable=false

[Types]
Name: Custom; Description: Custom installation; Flags: iscustom

[Components]
Name: VB5RT; Description: Visual Basic Runtime 5.0; Flags: disablenouninstallwarning
Name: VB6RT; Description: Visual Basic Runtime 6.0; Flags: disablenouninstallwarning
Name: DCOM95; Description: DCOM for Windows 95; Flags: disablenouninstallwarning restart; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0
Name: DCOM98; Description: DCOM for Windows 98; MinVersion: 4.1,0; Flags: disablenouninstallwarning
Name: MDAC; Description: Microsoft Data Access Components; Flags: disablenouninstallwarning restart; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0

[Files]
; START VISUAL BASIC
Source: Redist\VB_Runtime\STDOLE2.TLB; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regtypelib; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
Source: Redist\VB_Runtime\MSVBVM50.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regserver; CopyMode: alwaysskipifsameorolder; Components: VB5RT
Source: Redist\VB_Runtime\MSVBVM60.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regserver; CopyMode: alwaysskipifsameorolder; Components: VB6RT
Source: Redist\VB_Runtime\OleAut32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regserver; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
Source: Redist\VB_Runtime\OlePro32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regserver; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
Source: Redist\VB_Runtime\AsycFilt.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
Source: Redist\VB_Runtime\Ctl3d32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
Source: Redist\VB_Runtime\ComCat.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall regserver; CopyMode: alwaysskipifsameorolder; Components: VB5RT VB6RT
; END VISUAL BASIC
; START DCOM
Source: Redist\DCOM\dcom95.EXE; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0; Components: DCOM95
Source: Redist\DCOM\dcom98.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.1,0; Components: DCOM98
Source: Redist\DCOM\dcm95cfg.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.0,0; Components: DCOM95 DCOM98
; END DCOM
; START MDAC
Source: Redist\MDAC\mdac_typ.exe; DestDir: {tmp}; CopyMode: alwaysoverwrite; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0; Components: MDAC
; END MDAC

[Run]
; START DCOM
Filename: {tmp}\dcom95.EXE; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Components: DCOM95; MinVersion: 4.0,0; OnlyBelowVersion: 4.1,0
Filename: {tmp}\dcom98.exe; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Components: DCOM98; MinVersion: 4.1,0
Filename: {tmp}\dcm95cfg.exe; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Components: DCOM95 DCOM98; MinVersion: 4.0,0
; END DCOM
; START MDAC
Filename: {tmp}\mdac_typ.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; Components: MDAC; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0
; END MDAC

ISTool can now be found here: www.istool.org
ISTool: makes Inno scripts much easier to make, as it puts a GUI over the process. You can still manually edit the script as well from under the GUI.

VBP to Inno Setup Script Converter: http://www.randem.com/innoscript/innoscript.htm

Migrate from Microsoft's Package and Deployment Wizard or just go straight to Inno Setup from a VBP file with InnoScript!!